home *** CD-ROM | disk | FTP | other *** search
/ PsL Monthly 1993 December / PSL Monthly Shareware CD-ROM (December 1993).iso / prgmming / dos / asm / pc370_3.exe / lha / PET.ALC < prev    next >
Text File  |  1987-01-01  |  2KB  |  72 lines
  1.     TITLE 'PET - PRINT ELAPSED TIME IN SECONDS SINCE LAST CALL'
  2. *
  3. *
  4. * 04/08/85 CODED
  5. * 04/28/85 ADD DISPLAY OF DATE, TIME, INSTRUCTION COUNTER, INS/SEC
  6. * 01/01/87 CHANGE SVC 16 TO USE CONTENTS OF R1 FOR COUNT IN R2.0
  7. *
  8. PET      CSECT
  9.     USING *,R15
  10.     STM   R14,R15,RSAVE
  11.     L     R15,=V(DAT)       DISPLAY DATE AND TIME
  12.     BALR  R14,R15
  13.     USING *,R14
  14.     LM    R14,R15,RSAVE
  15.     DROP  R14
  16.     SVC   ICNTSVC
  17.     LR    R0,R1
  18.     L     R1,INSCOUNT
  19.     ST    R0,INSCOUNT       SAVE LAST INSTR. COUNT
  20.     CVD   R0,PWORK
  21.     MVC   DCOUNT,MASKCNT
  22.     ED    DCOUNT,PWORK+4
  23.     LA    R2,DCNTMSG
  24.     SVC   WTO               DISPLAY CURRENT INSTRUCTION COUNTER
  25.     SR    R0,R1
  26.     ST    R0,INSDIFF        SAVE TOTAL SINCE LAST CALL
  27.     L     R15,=V(TIMER)
  28.     BALR  R14,R15
  29.     USING *,R14
  30.     LM    R14,R15,RSAVE
  31.     DROP  R14
  32.     L     R1,TSAVE
  33.     ST    R0,TSAVE         SAVE CURRENT TIMER VALUE IN 100TH SEC.
  34.     LTR   R1,R1
  35.     BZR   R14              EXIT NOW IF FIRST CALL
  36.     SR    R0,R1
  37.     ST    R0,SEC100        SAVE ELAPSED TIME IN 100TH SEC
  38.     CVD   R0,PWORK
  39.     MVC   DTIME,MASKSEC
  40.     ED    DTIME,PWORK+4
  41.     L     R1,INSDIFF
  42.     MH    R1,=H'100'       SET R0-R1 = 100 * INSTRUCTIONS IN INTERVAL
  43.     SR    R0,R0
  44.     D     R0,SEC100        SET R1 = INSTRUCTIONS PER SECOND
  45.     CVD   R1,PWORK
  46.     MVC   DIPS,MASKCNT
  47.     ED    DIPS,PWORK+4
  48.     LA    R2,DTIMEMSG
  49.     SVC   WTO
  50.     BR    R14
  51. R15      EQU   15
  52. R14      EQU   14
  53. R2       EQU   2
  54. R1       EQU   1
  55. R0       EQU   0
  56. RSAVE    DC    2F'0'
  57. TSAVE    DC    F'0'
  58. INSCOUNT DC    F'0'
  59. INSDIFF  DC    F'0'
  60. SEC100   DC    F'0'
  61. PWORK    DC    D'0'
  62. MASKSEC  DC    X'402020',C',',X'202120',C'.',X'2020'
  63. MASKCNT  DC    X'4020',C',',X'202020',C',',X'202020'
  64. DCNTMSG  DC    C' INSTRUCTION COUNTER ='
  65. DCOUNT   DC    CL10' Z,ZZZ,ZZZ',C'$'
  66. DTIMEMSG DC    C' ELAPSED TIME ='
  67. DTIME    DC    CL10' ZZ,ZZ9.99',C' SEC    INSTR/SEC = '
  68. DIPS     DC    CL10' Z,ZZZ,ZZZ',C'$'
  69. ICNTSVC  EQU   16
  70. WTO      EQU   209
  71.     END
  72.